plugins {
    id("java-library")
    id("com.gradleup.shadow") version "9.4.1"
    id("xyz.jpenilla.run-paper") version "3.0.2"
}

repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")

    maven {
        name = "axolotsh-repository"
        url = uri("https://maven.axolotsh.org/releases")
    }
    maven {
        name = "scarsz-repository"
        url = uri("https://nexus.scarsz.me/content/groups/public/")
    }
}

dependencies {
    implementation("io.github.axolotsh:localizationlib:1.4.2")
    implementation("io.github.axolotsh:registrylib:1.0")

    compileOnly("org.projectlombok:lombok:1.18.44")
    annotationProcessor("org.projectlombok:lombok:1.18.44")

    compileOnly("dev.jorel:commandapi-paper-core:11.2.0")
    compileOnly("dev.jorel:commandapi-paper-annotations:11.2.0")
    annotationProcessor("dev.jorel:commandapi-spigot-annotations:11.2.0")

    compileOnly("com.discordsrv:discordsrv:1.28.0")
    
    compileOnly("io.papermc.paper:paper-api:26.1.1.build.+")
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(25)
}

tasks {
    build {
        dependsOn(shadowJar)
    }

    runServer {
        minecraftVersion("26.1.1")
        jvmArgs("-Xms2G", "-Xmx2G", "-Dcom.mojang.eula.agree=true")

        downloadPlugins {
            hangar("CommandAPI", "11.2.0")
            modrinth("DiscordSRV", "1.30.4")
        }
    }

    processResources {
        val props = mapOf(
            "version" to project.version,
            "description" to (project.description ?: ""))
            
        filesMatching("plugin.yml") {
            expand(props)
        }
        filesMatching("paper-plugin.yml") {
            expand(props)
        }
    }
}