PluginUtils/plugin-utils/build.gradle.kts

plugins {
    id("java-library")
    id("maven-publish")
}

group = providers.gradleProperty("group").get()
version = providers.gradleProperty("version").get()

repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")

    maven {
        name = "axolotsh-repository"
        url = uri("https://maven.axolotsh.org/snapshots")
    }
}

dependencies {
    compileOnly("org.projectlombok:lombok:1.18.46")
    annotationProcessor("org.projectlombok:lombok:1.18.46")

    compileOnly("com.google.inject:guice:7.0.0")

    compileOnly("dev.jorel:commandapi-paper-core:11.2.0")

    compileOnly("io.papermc.paper:paper-api:26.1.2.build.+")
}

java {
    toolchain.languageVersion = JavaLanguageVersion.of(25)
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            from(components["java"])

            groupId = project.group.toString()
            artifactId = project.name
            version = project.version.toString()
        }
    }

    repositories {
        maven {
            name = "Reposilite"
            
            val releasesUrl = "https://maven.axolotsh.org/releases"
            val snapshotsUrl = "https://maven.axolotsh.org/snapshots"
            url = uri(if (version.toString().endsWith("SNAPSHOT")) snapshotsUrl else releasesUrl)

            credentials {
                username = providers.gradleProperty("reposiliteUser").orNull ?: "admin"
                password = providers.gradleProperty("reposilitePassword").orNull ?: "password"
            }
        }
    }
}