mirror of
https://source.denx.de/u-boot/u-boot.git
synced 2026-06-13 15:03:58 +03:00
f150843499
With commit0535e46d55("scripts/dtc: Update to upstream version v1.7.2-35-g52f07dcca47c") it is now a fatal error to U-Boot if our device tree is not 8-byte aligned. In commit85f586035d("ARM: OMAP2+: Pad SPL binary to 8-byte alignment before DTB") Beleswar Padhi explains that we must have ALIGN(x) statements inside of a section to ensure that padding is included and not simply that the linker address counter is incremented. To that end, this patch: - Aligns the final section before _end (for U-Boot) or _image_binary_end (for xPL phases) by 8-bytes by adding '. = ALIGN(8);' to the final section before the symbol. - Remove a now-spurious '. = ALIGN(x);' statement that was intended to provide the above alignments. - Ensure that we do have alignment by adding an ASSERT so that when not aligned we fail to link (and explain why). Reviewed-by: Leo Yu-Chi Liang <ycliang@andestech.com> Reviewed-by: Ilias Apalodimas <ilias.apalodimas@linaro.org> Signed-off-by: Tom Rini <trini@konsulko.com>
63 lines
1.2 KiB
Plaintext
63 lines
1.2 KiB
Plaintext
/* SPDX-License-Identifier: GPL-2.0+ */
|
|
/*
|
|
* Based on arch/riscv/cpu/u-boot.lds, which is
|
|
* Copyright (C) 2017 Andes Technology Corporation
|
|
* Rick Chen, Andes Technology Corporation <rick@andestech.com>
|
|
*
|
|
* and arch/mips/cpu/u-boot-spl.lds.
|
|
*/
|
|
MEMORY { .spl_mem : ORIGIN = IMAGE_TEXT_BASE, LENGTH = IMAGE_MAX_SIZE }
|
|
MEMORY { .bss_mem : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
|
|
LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
|
|
|
|
OUTPUT_ARCH("riscv")
|
|
ENTRY(_start)
|
|
|
|
SECTIONS
|
|
{
|
|
. = ALIGN(4);
|
|
__image_copy_start = ADDR(.text);
|
|
.text : {
|
|
arch/riscv/cpu/start.o (.text)
|
|
*(.text*)
|
|
} > .spl_mem
|
|
|
|
. = ALIGN(4);
|
|
.rodata : {
|
|
*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
|
|
} > .spl_mem
|
|
|
|
. = ALIGN(4);
|
|
.data : {
|
|
*(.data*)
|
|
} > .spl_mem
|
|
. = ALIGN(4);
|
|
|
|
__u_boot_list : {
|
|
KEEP(*(SORT(__u_boot_list*)));
|
|
} > .spl_mem
|
|
|
|
. = ALIGN(4);
|
|
|
|
.binman_sym_table : {
|
|
__binman_sym_start = .;
|
|
KEEP(*(SORT(.binman_sym*)));
|
|
__binman_sym_end = .;
|
|
. = ALIGN(8);
|
|
} > .spl_mem
|
|
|
|
_end = .;
|
|
_image_binary_end = .;
|
|
__image_copy_end = .;
|
|
|
|
.bss : {
|
|
__bss_start = .;
|
|
*(.bss*)
|
|
. = ALIGN(8);
|
|
__bss_end = .;
|
|
} > .bss_mem
|
|
}
|
|
|
|
ASSERT(_image_binary_end % 8 == 0, \
|
|
"_image_binary_end must be 8-byte aligned for device tree");
|